Quellcode

uses ShlObj, ActiveX;

function SelectComputer(const Caption: string; out Computer: string): Boolean;
var BrowseInfo: TBrowseInfo; 
    ShellMalloc: IMalloc; 
    RootItemIDList, ItemIDList: PItemIDList; 
    Buffer: PChar;
begin 
  Result := False; 
  Computer := ''; 
  FillChar(BrowseInfo, SizeOf(BrowseInfo), 0); 
  if (ShGetMalloc(ShellMalloc) = S_OK) and (ShellMalloc <> nil) then 
  begin 
    Buffer := ShellMalloc.Alloc(MAX_COMPUTERNAME_LENGTH + 1); 
    try 
      SHGetSpecialFolderLocation(0, CSIDL_NETWORK, RootItemIDList); 
      with BrowseInfo do begin 
        hwndOwner := Application.Handle; 
        pidlRoot := RootItemIDList; 
        pszDisplayName := Buffer; 
        lpszTitle := PChar(Caption); 
        ulFlags := BIF_BROWSEFORCOMPUTER; 
      end; 
      ItemIDList := ShBrowseForFolder(BrowseInfo); 
      Result := ItemIDList <> nil; 
      if Result then begin 
        ShellMalloc.Free(ItemIDList); 
        Computer := '\\' + AnsiUpperCase(Buffer); 
      end; 
    finally 
      ShellMalloc.Free(RootItemIDList); 
      ShellMalloc.Free(Buffer); 
    end;
  end;
end;

procedure TMainForm.btnBrowseClick(Sender: TObject);
var s: string;
begin 
  SelectComputer('Select computer', s); 
  if s <> '' then edtComputerName.Text := s;
end;